一、使用Command对象和Parameter对象传递参数
本讲将主要使用Microsoft SQL Server7.0数据库，先建立一个连接文件AdoSQL7.asp备用，以后用到时不再特别说明。
<% ''AdoSQL7.asp
Option Explicit
Response.Expires = 0
''第一部分: 建立连接
Dim Cnn, StrCnn
Set Cnn = Server.CreateObject("ADODB.Connection")
StrCnn = "Provider=sqloledb; User ID=sa; Password=; Initial Catalog=pubs; Data Source=ICBCZJP"
Cnn.Open StrCnn
%>
注意：自己使用时要将Data Source设为你的数据库服务器所在的机器名。
另外，以前使用Access数据库时，用Microsoft Access97可以很方便的查看字段及数据，而使用SQL Server数据库，尤其是并不在数据库服务器，而是在另一台机器上调试ASP脚本时，要查看字段及数据便需另外安装工具，这里向你提供一个工具：Msqry32.exe（Microsoft Query），这个文件随Office97安装，一般位于目录“Microsoft Office/Office”下。
例wuf70.asp：
<%@ LANGUAGE="VBSCRIPT" %>
<!--#include file="AdoSQL7.asp"-->
<!--#include file="adovbs.inc"-->
<% '' wuf70.asp
Dim cmdTest, prmTest, rsTest
''创建 Command 对象
Set cmdTest = Server.CreateObject("ADODB.Command")
‘Recordset、Command对象都可以通过ActiveConnection属性来连接Connection对象
cmdTest.ActiveConnection = Cnn
''SQL命令 - 含两个参数， 用 ？ 表示
cmdTest.CommandText = "Update jobs Set job_desc = ? Where job_id = ?"
''设命令类型为 SQL 语句
cmdTest.CommandType = adCmdText
''Prepared 属性决定是否将 SQL 命令先行编译，将其设为True，可以加快运行
cmdTest.Prepared = True
''创建 Parameter 对象
Set prmTest=cmdTest.CreateParameter("job_desc",adVarChar,adParamInput,50,"网络")
''将数据追加到 Parameters 数据集合中
cmdTest.Parameters.Append prmTest
Set prmTest = cmdTest.CreateParameter("job_id",adSmallInt,adParamInput,,"12")
cmdTest.Parameters.Append prmTest
''执行修改 – 不需要返回结果，简单的使用cmdTest.Execute 就可以了
cmdTest.Execute
''重新设置参数运行 – 便可修改另一条数据
cmdTest.Parameters("job_id") = "1"
cmdTest.Parameters("job_desc") = "测试"
cmdTest.Execute
''重新设置参数运行
cmdTest("job_id") = "14"
cmdTest("job_desc") = "金融"
cmdTest.Execute
Set rsTest = Cnn.Execute("Select job_id,job_desc From jobs")
While Not rsTest.EOF
Response.Write rsTest(0) & rsTest(1) & "<br>"
rsTest.MoveNext
Wend
Cnn.close : Set prmTest = Nothing
Set cmdTest = Nothing: Set Cnn = Nothing
%>
分析：
1．Command对象的CreateParameter方法用来为SQL命令或存储过程建立参数对象，共有五个参数（五个参数都是可选项）：
第一个参数：参数对象的名称；
第二个参数：参数对象的数据类型，种类太多，还是参考ADO帮助吧，这里adVarChar（字符串值）、adSmallInt（2 字节带符号整型）；
第三个参数：参数类型。可以是：adParamInput（指示输入参数）、adParamOutput（ 指示为输出参数）、adParamReturnValue（指示为返回值）、adParamUnknown（指示参数类型无法确定）、adParamInputOutput（指示为输入/输出参数）；
第四个参数：参数的数据长度，最好指定为与数据库中对应字段长度相等，以免使用时出错，尤其数据类型为VarChar时，如果是整型或日期型则不必提供该值；
第五个参数：参数的设置初值。
2．cmdTest.Parameters.Append方法增加一个Parameter对象到Parameters数据集合中，从本例中也可看到如何使用多个参数。
3．从本例可以看到，只需要重新设定输入参数，便可执行对其他数据的修改，非常方便，这一思路在编程时也是最常用的方法之一。
4．重设参数，既可以使用cmdTest.Parameters，也可以省略为cmdTest("job_id")。
二、在ASP中使用存储过程
什么是存储过程（存储过程位于数据库服务器中，是一个SQL语句的集合，可包含一个或多个SQL语句）、怎样创建存储过程不属于本讲座的内容，本讲座主要是举例说明在ASP中如何调用存储过程。
使用存储过程的好处是大大的，存储过程比在ASP脚本中运行SQL命令效率更高；可以提高整体性能并减轻网络负载（减少了在网络服务器和数据服务器之间的交互）；可以优化ASP代码和增强代码灵活性等等。
（一）在存储过程中使用输入参数
本例中使用的存储过程为SQL Server7.0自带的“byroyalty”，里面的一条SQL语句非常简单，无非是多了一个CREATE PROCEDURE byroyalty，并且有一个输入参数为@percentage：
CREATE PROCEDURE byroyalty @percentage int
AS
select au_id from titleauthor
where titleauthor.royaltyper = @percentage
serve by www.cidu.net
例wuf71.asp
<% @LANGUAGE = VBScript %>
<!--#include file="AdoSQL7.asp"-->
<!--#include file="adovbs.inc"-->
<% '' wuf71.asp
Dim cmdTest, prmTest, rsTest
Set cmdTest = Server.CreateObject("ADODB.Command")
cmdTest.CommandText = "byroyalty" ''存储过程名
''设命令类型为 存储过程
cmdTest.CommandType = adCmdStoredProc
''创建 Parameter 对象
Set prmTest = Server.CreateObject("ADODB.Parameter")
‘Type属性对应wuf70.asp中的第二个参数
prmTest.Type = adInteger ''4 字节的带符号整型
‘Direction属性对应wuf70.asp中的第三个参数
prmTest.Direction = adParamInput
‘Value属性对应wuf70.asp中的第五个参数
prmTest.Value = 30
cmdTest.Parameters.Append prmTest
Set cmdTest.ActiveConnection = Cnn
‘需要返回一个记录集，故使用Set rsTest = cmdTest.Execute
Set rsTest = cmdTest.Execute
While Not rsTest.EOF
Response.Write rsTest(0) & "<br>"
rsTest.MoveNext
Wend
Cnn.close
Set rsTest = Nothing : Set prmTest = Nothing
Set cmdTest = Nothing: Set Cnn = Nothing
%>
CommandText属性既可以指定SQL命令，也可以指定为存储过程或者是表名称。
在本例中，创建Parameter对象与wuf70.asp略有不同，其实仔细看看，意思也是差不多的，本例还有两个属性未用：prmTest.Name、prmTest.Size，加上Type、Direction和Value，对应于wuf70.asp中的五个参数。
（二）使用输出参数
从数据库表中取得一个记录或计算一个值时，需要使用返回输出参数的存储过程。为了举例，先在SQL Server的pubs库中新建一存储过程OUTemploy，该存储过程需要输入两个日期，然后输出一个最大值。
CREATE PROCEDURE OUTemploy
(
@job_lvl tinyint OUTPUT,
@hire_date1 datetime,
@hire_date2 datetime
)
AS
select @job_lvl = MAX(job_lvl) from employee
where hire_date >= @hire_date1 and hire_date <= @hire_date2
有多种方法可以建立存储过程：
1．使用Microsoft SQL Server的Enterprise Manager，打开后在左边的树目录中依次打开：Console Root – Microsoft SQL Servers – SQL Server Group – ICBCZJP(Windows NT) – databases – pubs – stored procedure – New stored procedure，输入存储过程后，还可对其进行语法检测；
2．使用Microsoft SQL Server的Query Analyzer，先连接数据库服务器并选择pubs数据库。输入上面的存储过程并点击Execute Query(或按F5)；
3．使用VB6.0，打开菜单“视图”/“数据视图窗口”后，右键单击“数据链接”/“新建数据链接”；
4．使用ASP脚本创建存储过程，例wuf75.asp：
<% @LANGUAGE = VBScript %>
<!--#include file="AdoSQL7.asp"-->
<!--#include file="adovbs.inc"-->
<% '' wuf75.asp
Dim StrSQL
''注: & Chr(10) & Chr(13) 完全可以不要, 主要是为了好看
StrSQL="CREATE PROCEDURE OUTemploy ( @job_lvl tinyint OUTPUT, " & Chr(10) & Chr(13) &_
"@hire_date1 datetime, @hire_date2 datetime) AS " & Chr(10) & Chr(13) &_
"select @job_lvl = MAX(job_lvl) from employee " &_
"where hire_date >= @hire_date1 and hire_date <= @hire_date2"
Cnn.Execute StrSQL
Response.Write "创建存储过程成功"
Cnn.close: Set Cnn = Nothing
%>
存储过程创建后，除了使用菜单，你还可以使用SQL语句“Drop Procedure OUTemploy”删除它。
例wuf72.asp – 把所需要的输入参数送入存储过程并取得输出结果。
<% @LANGUAGE = VBScript %>
<!--#include file="AdoSQL7.asp"-->
<!--#include file="adovbs.inc"-->
<% '' wuf72.asp
Dim cmdTest, prmTest
Set cmdTest = Server.CreateObject("ADODB.Command")
cmdTest.ActiveConnection = Cnn
cmdTest.CommandText = "OUTemploy" ''存储过程名
cmdTest.CommandType = adCmdStoredProc
''创建 Parameter 对象
Set prmTest = cmdTest.CreateParameter("job_lvl",adTinyInt,adParamOutput)
cmdTest.Parameters.Append prmTest
''adTinyInt - 1 字节带符号整型
''adDbDate - 日期值 (yyyymmdd)
Set prmTest = cmdTest.CreateParameter("hiredate1",adDBDate,adParamInput,,"1993-05-09")
cmdTest.Parameters.Append prmTest
Set prmTest = cmdTest.CreateParameter("hiredate2",adDBDate,adParamInput,,"1994-02-01")
cmdTest.Parameters.Append prmTest
cmdTest.Execute
‘下面三种表达方式意思一样
Response.Write cmdtest("job_lvl") & "<br>"
Response.Write cmdTest.Parameters("job_lvl") & "<br>"
Response.Write cmdTest.Parameters("job_lvl").Value
Cnn.close
Set prmTest = Nothing
Set cmdTest = Nothing: Set Cnn = Nothing
%>
（三）使用返回代码参数
用Return语句可以从存储过程返回不同的返回代码，如下面存储过程先取得一个记录集，然后，若有叫Margaret的雇员则返回1，否则返回0。
Create Procedure Returnemploy
AS
select emp_id, fname from employee
If Exists(Select fname From employee Where fname=''Margaret'')
Return(1)
Else
Return(0)
例wuf73.asp
<% @LANGUAGE = VBScript %>
<!--#include file="AdoSQL7.asp"-->
<!--#include file="adovbs.inc"-->
<% '' wuf73.asp
Dim cmdTest, prmTest, rsTest
Set cmdTest = Server.CreateObject("ADODB.Command")
cmdTest.ActiveConnection = Cnn
cmdTest.CommandText = "Returnemploy" ''存储过程名
cmdTest.CommandType = adCmdStoredProc
Set prmTest = cmdTest.CreateParameter("ReturnValue",adInteger,adParamReturnValue)
cmdTest.Parameters.Append prmTest
Set rsTest = cmdTest.Execute()
While Not rsTest.EOF
Response.Write rsTest(0) & " ][ " & rsTest(1) & "<br>"
rsTest.MoveNext
Wend
rsTest.Close: Set rsTest = Nothing
''返回 cmdtest("ReturnValue") 之前,必须先关闭rsTest, 否则结果错误
If cmdtest("ReturnValue") = 1 Then
Response.Write "有该雇员"
Else
Response.Write "无该雇员"
End If
Cnn.close
Set prmTest = Nothing
Set cmdTest = Nothing: Set Cnn = Nothing
%>
三、如何处理大数据
这里的“大数据”主要是指Text（大文本）和image（图像）字段，采用前面所述的方法无法正确获取其数据。必须首先使用Size = rsTest(0).ActualSize获取字段值的实际长度，然后再使用rsTest(0).GetChunk(Size)取得数据。在实际使用过程中，由于这些字段都比较大，为了节省、合理使用服务器资源，一般均采取分段读取的方法。例wuf74.asp:
<% @LANGUAGE = VBScript %>
<!--#include file="AdoSQL7.asp"-->
<!--#include file="adovbs.inc"-->
<% '' wuf74.asp
Dim StrSQL, rsTest
‘pr_info 是一个文本字段
StrSQL = "Select pr_info,pub_id From pub_info"
Set rsTest = Cnn.Execute(StrSQL)
Dim BasicSize, BeginSize, LText
Do While Not rsTest.EOF
Response.Write rsTest(1) & "<br>"
‘每次读取 1024字节
BasicSize = 1024
BeginSize = 0
While BeginSize < rsTest(0).ActualSize
LText = rsTest(0).GetChunk(BasicSize)
BeginSize = BeginSize + BasicSize
‘逐段输出到客户端
Response.Write LText
Wend
Response.Write "<br><br>"
rsTest.MoveNext
Loop
Cnn.close
Set rsTest = Nothing: Set Cnn = Nothing
%>
在本例中，每次最多读取1024字节，分多次读完。反之，如果将大数据写至数据库中，方法类似上面，不过不是使用GetChunk方法，而是使用AppendChunk方法：
rsTest(0).AppendChunk Ltext
注意：最后介绍一个关于SQL Server数据库的小技巧，如果你遇到过这种情况：数据库的中文数据显示出来均是乱码，请不要惊慌。你只要去我的站点下载sqlsrv32.dll覆盖“C:/Windows/System”下的同名文件就可以了。问题发生的源头是SQL Server驱动程序，典型的情况发生在Windows98第二版（SQL Server驱动程序的版本号为3.70.06.23）或Windows2000中或者安装了MDAC2.5（版本号为3.70.08.20）。
分享到：
相关推荐
本例归纳了一些。net中分页的存储过程，值得初学者一看和学习。有详细的表和几种不同的存储过程
该例是asp.net教学中常见案例，涉及多个操作（登录验证、对数据表的增删改查），而且选用开发过程中常见的视图、存储过程对数据库实现相关操作。主要供初学者学习使用。 特别提醒：代码环境MS.net2012，数据库环境...
sql 代码如下:CREATE PROCEDURE Proname //使用CREATE PROCEDURE 创建存储过程 Proname为存储过程名称 @Lname VARCHAR(30) //定义传入的参数 AS SET ... 下面就开始使用ASP操作这个存储过程。 代码如下://下面是建
该例是asp.net教学中常见案例，主要通过视图、存储过程的方式访问数据库（非三层架构），操作包含逻辑完成的增删改查，主要供初学者学习使用。 特别提醒：代码环境MS.net2012，数据库环境SQL Server2012。Webconfig...
使用存储过程能有效提高数据访问效率，存储过程会在第一次执行时被编译，应用程序可以直接从编译后的文件中获取相应结果； 减少流量和通信。使用存储过程访问数据，可以降低对网络带宽的需求，减少应用程序读取...
具有LoadStoredProc方法的DbContext扩展，它使用提供的DbDataReader扩展来创建IStoredProcBuilder ，以使用自定义映射策略来构建存储过程。 该方法处理： 结果集中的额外列 模型中的额外属性 结果集中为空值 结果...
所以最好在数据访层分页,如果这样就要使用存储过程来分页.以下是以pubs 数据库中的employee表为例来进行数据分页的存储过程,你可以参考它根据实际情况来创建自己的存储过程. 注:@pageindex 数据页的索引,@...
也论该不该在项目中使用存储过程代替SQL语句 如何使数据库中的表更有弹性,更易于扩展 存储过程——天使还是魔鬼 如何获取MSSQLServer,Oracel,Access中的数据字典信息 C#中利用GetOleDbSchemaTable获取数据库内表信息...
下面我们分别看看在management studio中如何查看输出参数，返回值以及结果集，然后我们再在ASP.NET调用存储过程中如何获得输出参数，返回值以及结果集。 首先：在sql server management studio中查看输出参数，...
因此，开发这样一套管理软件成为很有必要的事情,在下面的各章中我们将以开发一套企业人事管理系统为例,谈谈其开发过程和所涉及到的问题及解决方法。 --------------摘要-------------- 人事管理系统是典型的信息...
而动态数据是指用户在使用平台的过程中所产生的业务数据，在实现业务中，这部分数据大部分都是读操作比较多，而写操作比较少，因此可以针对这部分数据根据特定的缓存失效策略机制来进行相应的缓存; 缓冲层的...
介绍了在WEB和ASP环境下开发的一个管理信息系统的过程。通过分析传统的人工管理汽车的不足，创建了一套行之有效的计算机管理汽车的方案。文章详细介绍了汽车管理信息系统的系统分析部分，包括可行性分析、数据流程...
解决办法：使用存储过程，参数不要用字符串拼接。简单改进办法：使用SqlHelper和OledbHelper 2、跨站脚本漏洞 解决办法：“默认禁止，显式允许”的策略。具体参考：从客户端检测到有潜在危险的Request.Form值，禁止...
全书分为15章：第1章和第2章介绍SQL Server 2005的基本知识及管理和开发工具：第3章～8章介绍数据库开发、事务日志、数据表和关键字的创建，Transact-SQL、视图和索引的使用，存储过程和触发器；第9章和第10章介绍...
将变量或方法声明为final，可以保证它们在使用中不被改变。被声明为final的变量必须在声明时给定初值，而在以后的引用中只能读取，不可修改。被声明为final的方法也同样只能使用，不能重载 finally?再异常处理时...
利用Microsoft SQL Server 2000建立数据库及其存储过程。这里给出两个必需的数据表，一是数据表News包含的字段有：编号、姓名、标题、关键字、内容、类型、来源部门和日期。字段说明如下： 二是数据表Reg包含的...
学生学籍管理系统是一个教育单位不可缺少的部分,它的内容对于学校的...因此，开发这样一套管理软件成为很有必要的事情,在下面的各章中将以开发一套学生学籍管理系统为例,谈谈其开发过程和所涉及到的问题及解决方法。